Gecko [ renovalkoronred.com.tr ]

Name	Size	Permission
bash_completion.sh	664 B	-rw-r--r--
bash_timestamps.sh	69 B	-rw-r--r--
checkip.sh	4.23 KB	-rwxr-xr-x
colorgrep.csh	196 B	-rw-r--r--
colorgrep.sh	201 B	-rw-r--r--
colorls.csh	1.7 KB	-rw-r--r--
colorls.sh	1.57 KB	-rw-r--r--
colorsysstat.csh	69 B	-rw-r--r--
colorsysstat.sh	56 B	-rw-r--r--
colorxzgrep.csh	162 B	-rw-r--r--
colorxzgrep.sh	183 B	-rw-r--r--
colorzgrep.csh	216 B	-rw-r--r--
colorzgrep.sh	220 B	-rw-r--r--
cpanel-php-composer.sh	548 B	-rwxr-xr-x
cpanel-user-commands.sh	513 B	-rw-r--r--
csh.local	80 B	-rw-r--r--
debuginfod.csh	674 B	-rw-r--r--
debuginfod.sh	596 B	-rw-r--r--
gawk.csh	1.08 KB	-rw-r--r--
gawk.sh	757 B	-rw-r--r--
lang.csh	2.43 KB	-rw-r--r--
lang.sh	2.26 KB	-rw-r--r--
less.csh	500 B	-rw-r--r--
less.sh	253 B	-rw-r--r--
locallib.csh	240 B	-rwxr-xr-x
locallib.sh	288 B	-rwxr-xr-x
modules.csh	105 B	-rw-r--r--
modules.sh	448 B	-rw-r--r--
scl-init.csh	284 B	-rw-r--r--
scl-init.sh	637 B	-rw-r--r--
sh.local	81 B	-rw-r--r--
vim.csh	106 B	-rw-r--r--
vim.sh	248 B	-rw-r--r--
which2.csh	120 B	-rw-r--r--
which2.sh	540 B	-rw-r--r--

Code Editor : colorls.csh

# skip everything for non-interactive shells
if (! $?prompt) exit

# color-ls initialization
if ( $?USER_LS_COLORS ) then
  if ( "$USER_LS_COLORS" != "" ) then
     #when USER_LS_COLORS defined do not override user
     #specified LS_COLORS and use them
     goto finish
  endif
endif

alias ll 'ls -l'
alias l. 'ls -d .*'
set COLORS=/etc/DIR_COLORS

if ($?TERM) then
  if ( -e "/etc/DIR_COLORS.256color" ) then
    if ( "`/usr/bin/tput colors`" == "256" ) then
       set COLORS=/etc/DIR_COLORS.256color
    endif
  endif
  if ( -e "/etc/DIR_COLORS.$TERM" ) then
     set COLORS="/etc/DIR_COLORS.$TERM"
  endif
endif
if ( -f ~/.dircolors ) set COLORS=~/.dircolors
if ( -f ~/.dir_colors ) set COLORS=~/.dir_colors
if ($?TERM) then
  if ( -f ~/.dircolors."$TERM" ) set COLORS=~/.dircolors."$TERM"
  if ( -f ~/.dir_colors."$TERM" ) set COLORS=~/.dir_colors."$TERM"
endif
set INCLUDE="`/usr/bin/cat "$COLORS" | /usr/bin/grep '^INCLUDE' | /usr/bin/cut -d ' ' -f2-`"

if ( ! -e "$COLORS" ) exit

set _tmp="`/usr/bin/mktemp .colorlsXXX -q --tmpdir=/tmp`"
#if mktemp fails, exit when include was active, otherwise use $COLORS file
if ( "$_tmp" == '' ) then
  if ( "$INCLUDE" == '' ) then
    eval "`/usr/bin/dircolors -c $COLORS`"
  endif
  goto cleanup
endif

if ( "$INCLUDE" != '' ) /usr/bin/cat "$INCLUDE" >> $_tmp
/usr/bin/grep -v '^INCLUDE' "$COLORS" >> $_tmp

eval "`/usr/bin/dircolors -c $_tmp`"

/usr/bin/rm -f $_tmp

if ( "$LS_COLORS" == '' ) exit
cleanup:
set color_none=`/usr/bin/sed -n '/^COLOR.*none/Ip' < $COLORS`
if ( "$color_none" != '' ) then
   unset color_none
   exit
endif
unset color_none
unset _tmp
unset INCLUDE
unset COLORS

finish:
alias ll 'ls -l --color=auto'
alias l. 'ls -d .* --color=auto'
alias ls 'ls --color=auto'

${this.title}

Code Editor : colorls.csh